ZmtDeployPlugin.groovy

package de.zmt.gradle;

import org.gradle.api.*

/*
 * Deploy plugin for simulations based on zmt.core
 * <p>
 * Adds 'deployZip' task for uploading to dochost. A CHANGES file is also
 * added containing git tags and their descriptions.
 */
public class ZmtDeployPlugin implements Plugin<Project> {
    private static final def CONFIGURE = {
        apply plugin: "org.hidetake.ssh"
    
        remotes {
            dochost {
                host = determineCredentials.host
                knownHosts = allowAnyHosts
                user = credentials.dochostUser
                password = credentials.dochostPw
            }
        }
    
        task('deployZip') {
            group = 'Upload'
            description = 'Uploads zip distribution to dochost.'
            dependsOn distZip, determineCredentials
        }

        deployZip.doLast {
            println "\nConnecting to ${remotes.dochost.host}..."
            ssh.run {
                session(remotes.dochost) {
                    def remoteTargetDir = determineCredentials.wwwPath + 'dist'
                    
                    // create target directory on remote
                    execute "mkdir -p ${remoteTargetDir}"
                    
                    put from: distZip.archivePath, into: remoteTargetDir
                    // create CHANGES file from git version list
                    put text: obtainVersionListFromGit(project), into: remoteTargetDir + '/CHANGES'
                }
            }
        }
    }
    
    private static String obtainVersionListFromGit(Project project) {
        def output = new ByteArrayOutputStream()
        
        try {
            project.exec {
                commandLine 'git', 'tag', '-n99'
                standardOutput = output
            }
        }
        catch (org.gradle.process.internal.ExecException e) {
            println "git tag for ${project.name} failed. Cannot obtain version list."
            return ''
        }
        return output.toString().trim()
    }

    @Override
    void apply(Project project) {
        project.configure(project, CONFIGURE)
    }
}